home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 6
/
FM Towns Free Software Collection 6.iso
/
t_os
/
mopterm
/
mopterm.syn
< prev
next >
Wrap
Text File
|
1993-07-08
|
47KB
|
1,227 lines
ＭＯＰＴＥＲＭオートパイロット制御文（第十三版）
（ＭＯＰＴＥＲＭ Ｖｅｒ２．０２用）
１９９２年 ７月
MOPTERMオートパイロット制御文はテキストファイル上に制御文列を置くことで，
それに従って，センタへのアクセス，掲示版のダウンなどを自動的に行うもので
す。テキストファイルの作り方は「Townsシステムソフトウエア使いこなしガイド」
のP.244「テキスト編集の使い方」等を参考にして下さい。
なお，MOPTERMオートパイロット制御文を入れたテキストファイルの名前は，最
後の４文字が「.PLT」になるようにして下さい。他のオートパイロットファイルか
ら，間接的に呼び出される手続きだけの制御文ファイルの場合は，｢.PLP｣にして下
さい。
１．オートパイロット制御文ファイルの実行方法
オートパイロット制御文を入れたテキストファイルの使い方は３つあります。
一つは，MOPTERMをアイコン登録して起動する場合に，登録時のパラメータに記述
する方法です。もう，一つは，MOPTERM起動後にメニューから起動する方法です。
そして，最後は，送信入力行で指定するものです。
１．１ 起動時のパラメターでの指定
パラメータとして登録する場合は，MOPTERM.EXPをアイテム登録する際のパラメ
タに以下の形式で指定して下さい。
＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿
パラメータ ｜-x ファイル名 ｜
￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣
（ファイル名は，MS-DOSで言う所のパス名でも可能です。）
起動時のパラメタで指定されたオートパイロット制御文ファイルは，MOPTERMの
起動と同時に，解釈／実行を開始します。ですから，MOPTERMの設定に関する制御
文（５．１，５．２章を参照）は，この方法で指定すると便利です。
オートパイロットの動作中は，AUTOと書かれたアイコンだけが，少し，濃い色
で残っています。もし，動作を途中で止めたい場合は，これをクリックして下さ
い。
この停止の方法は，他の方法で起動した場合も同様です。
１．２ 動作中のメニューからの起動
MOPTERM動作中にメニューから使用する場合は，AUTOと書かれた，おかしなロボ
ット型のアイコンのクリックし，目的のファイルを選択して下さい。
その際，ファイルの一覧として表示されるのは，「xxxxxx.PLT」というように
ファイル名の最後の４文字（識別子）が「.PLT」のもののみです。
１．３ 通信入力行での指定
一行単位の送信モードの場合，通信入力行に，「$」で始まる文字列を記述して
リターンを押すと，「$」の後の部分をオートパイロットの制御文として処理しま
す。この場合，ファイルにオートパイロットの制御文が格納されているのではな
く，直接，入力する事になります。
もちろん，外部のファイルを実行する制御文を入れる事で，ファイルに格納され
た物を実行することもできます。
「$」の文字は，カストマイズ可能です。
例 シフトロックモードにする。
＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿
｜$shiftl({Yes}) ｜
￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣￣
次の章からは，制御文ファイルの中身の作成方法について記述します。
（申し訳ありませんが，誰にでも分かる記述では，ありません。ある程度，
他の，プログラム言語を，使った事のある人でないと理解できないかもしれませ
ん。 m(_ _)m 平易な記述を始めると，たぶん，百ページの以上の本になって
しまうでしょう。）
２．使用文字種
制御文ファイル上には，テキスト編集などで作成した文字列がおかれます。こ
れらの文字列は実行される場合に制御を直接指示する意味のある記号の並びとそ
れらの句切りとしてしか意味のない句切り記号により構成されます。意味のある
記号の間に複数個の句切り記号を挟むことができます。（意味のある記号がくっ
ついて，区別出来なくならない限り，挟まなくてもかまいません。）
１）区切り記号
句切り記号は以下のものです。
空白，改行，ＴＡＢ，コメント
コメントは以下の形式です。
/*任意の文字列*/
任意の文字列の部分に，「*/」を含めることはできません。また，「* 」及び，
「/ 」は半角の文字（１バイトのＪＩＳ文字/ ASCII文字）である必要があります。
２）意味のある記号
意味のある記号は以下のものです。
; , % ( ) [ ] { } | # @ && || < > <= >= == !=
= <> + - * / ! := 名前 （すべて，半角の文字です。）
名前は英字で始まり，英字又は数字が続いたものです。初めの８文字のみ，同
一性の判定のために使用されます。英字とは，英大文字と小文字であり，大文字
と小文字は同一性の判定では異なるものとなります。
意味のある記号は次に示す文法に従った順序で並べる必要があります。
３．文法
制御ファイルの意味のある部分は以下のような，文の並びによって構成され
ます。
＜文の並び＞：：＝ ＜文＞ ｜
＜文の並び＞ ; ＜文＞
これは，一つの文，又は，複数個の文を「;」で区切って並べたものという意味
です。：：＝の右側にある＜ ＞が構文上の項目を示し，：：＝の左側がその内
容を示します。｜はその両辺のどちらでもよいという意味です。
従って，上の記述は，＜文の並び＞というものは，一つの，＜文＞か，又は，
その後ろに，「；」で区切って次の文を並べたものという意味です。後ろ側の＜
文の並び＞に，前側の＜文の並び＞が何回も適用されることによって，いくら長
い＜文の並び＞もこの定義で良いことになります。
文には＜宣言文＞，＜実行文＞，＜変数宣言文＞，＜代入文＞と＜空文＞があ
ります。
＜文＞：：＝ ＜宣言文＞ ｜ ＜実行文＞ ｜ ＜変数宣言文＞ ｜
＜代入文＞ ｜ ＜空文＞
空文とはなにもないというもので，意味もありません。
＜空文＞：：＝
文の区切りとなる｢;｣，を余分に書いたり，何も入ってない文字列を実行
しても，何もしないだけで，エラーにはならないと言う事です。
１） 宣言文
＜宣言文＞：：＝ % ＜名前＞ ＜項＞
＜項＞ ：：＝ ＜因子＞ ｜ ＜因子＞ ＜演算子＞ ＜項＞ ｜
＜単項演算子＞ ＜項＞
＜因子＞ ：：＝ { ＜内容＞ } ｜ ＜名前＞ ｜ #ファイル名 ｜
@ ＜実行文＞ ｜ ( ＜項＞ ) ｜ ＜数字列＞
「%」の後の＜名前＞が，＜項＞で示される文字列を表す事を宣言します。ここ
で宣言された＜名前＞が＜実行文＞の中で評価されると，この宣言文の＜項＞で
示された文字列に置き代わります。
＜項＞が，一つの＜因子＞から成る場合は，その＜因子＞が表す文字列を表し
ます。
＜項＞が，複数の＜因子＞を＜演算子＞で区切りながら並べた物である場合，
それらの＜因子＞が表す文字列に＜演算子＞が示す処理をほどこした結果の物を
表します。＜単項演算子＞の場合は，後ろに続く＜項＞に対して＜単項演算子＞
が示す処理を行います。
＜演算子＞，＜単項演算子＞については，４）演算子を参照して下さい。
＜因子＞が「{ ＜内容＞ }」の形式の場合，＜因子＞は，＜内容＞に記述され
た文字列，そのものを表します。
＜内容＞に＜内容＞の中で対にならない「}」を含めることはできません。対に
なる「{」「}」とは，以下のいずれかに該当するものです。
－ 「{」と，その後，他の「{」を挟まずに最初にあらわれる「}」は，対にな
ります。
－ 「{」と，その後にあれわれる他の「{」と対にすることができない，その後
の最初の「}」とは対になります。
＜項＞が＜名前＞の場合は，その＜名前＞は既に評価された＜宣言文＞の中で
宣言されたものである必要があります。そして，＜項＞に示された＜名前＞は評
価されることによって，前に宣言された時点の内容におきかわります。その結果
新しい＜名前＞がその内容を示すものとして宣言されます。
「#ファイル名」は，フロッピーディスクや，ハードディスク上のファイルの参
照で，「#」の後に，２４文字以下の英数字（「_」「:」「\」を含む）列を付け
た物で，いわゆる MS-DOSのパス名／ファイル名です。この場合，＜因子＞は，そ
のファイルの中身である文字列を表します。
「@ ＜実行文＞」の形式の場合，この実行文が，評価され実行されます。この
実行文が結果の文字列を持つ物である場合，その結果の文字列を表すことになり
ます。
＜数字列＞とは，半角０～９までの数字の列を言います。＜因子＞が＜数字列
＞の場合，＜因子＞の値は，その数字の列をそのまま，文字列としたものです。
＜内容＞が数字の列の場合に「{ ＜内容＞ }」の，「{」と「 }」を省略でき
る，と見ることもできます。
実行文は結果の値を持つ場合がありますが，宣言文では，結果の値はありませ
ん。
注意：
＜名前＞は，英字で始まり，英字，又は，数字が任意個つながったものです。
ただし，＜名前＞の識別には頭の８バイトのみが使用されます。また，標準で提
供される＜文＞を表す＜名前＞と同一の＜名前＞を宣言した場合，宣言された＜
名前＞のが優先となるため，その＜名前＞の＜文＞が使えなくなります。
例 ダイヤル回線で０３０１２０１２３４に電話をかける。
%Tokyo {ATDP 0301201234};
dial (Tokyo)
これは, 以下のものと同じ意味です。
dial ({ATDP 0301201234})
また，以下のような使い方も可能です。
%CallTokyo ｛ %Tokyo {ATDP 0301201234};
Dial(Tokyo)
｝;
CallTokyo
だいぶ，回りくどいですが，結果は同じです。
２） 実行文
＜実行文＞：：＝＜因子＞ ｜
＜項＞ ( ＜パラメタ列 )
＜パラメタ列＞：：＝ ＜項＞ ｜
｜
＜パラメタ列＞ , ＜項＞
＜実行文＞の先頭にある＜因子＞，及び，＜パラメタ列＞で＜項＞として使用
される＜名前＞は，明に，あるいは，標準的に宣言された＜名前＞（文名）を示
します。＜実行文＞の頭に＜因子＞として使用される＜名前＞（文名）は＜文＞
の並びの順に評価され，対応する処理が実行されます。＜パラメタ列＞は，＜実
行文＞の実行にしたがって，評価されます。評価とは，＜名前＞をそれに対応す
る＜内容＞である文字列に置き換える作業のみですから，それが表す，処理を行
う（実行する）ことはありません。（ただし，wait文, case文, select文, loop
文, dialone文で，条件によって，＜パラメタ列＞内の＜項＞の内容を評価した結
果が実行されます。いわゆる，条件文，繰り返し文ということになるでしょう。）
＜パラメタ列＞は，＜項＞を「,」で区切って並べたものです。＜実行文＞によ
っては，＜パラメタ列＞の＜項＞は省略可能です。
＜実行文＞の実行には，以下の２つのケースがあります。
その＜実行文＞が実行可能な標準の＜名前＞（dial等）を頭に＜因子＞として
持つ場合は，その文の処理（４章に記述しています．）を行うことです。その場
合，結果の値は，対応する文の処理によって，返る場合と，帰らない場合があり
ます。
標準の名前以外の場合は，その＜因子＞の表す文字列を，＜文の並び＞として
実行することを意味します。＜因子＞が＜名前＞の場合は，＜文の並び＞を値と
して持つように，予め，宣言されている必要があります。
＜文の並び＞として実行する場合，＜文の並び＞の中の最後に有効な値を返し
た＜文＞の結果の値が，＜文の並び＞の結果の値となります。
例 標準名による文
type( {.00+});
例 宣言した名前による文
%ProcT {［Id］ type(Id)};
ProcT({PFFnnnnn\n}) /* これが, 実行文になります */
例 文字列
{
%ProcT {［Id］ type(Id) };
ProcT({PFFnnnnn}) /* これが, 実行文になります */
}
以上がひとつの文になります。この場合,ProcTはこの内部でのみ有効な＜名前
＞となります。
３） 変数宣言文
変数を宣言するための文です。
＜変数宣言文＞ ：：＝ var ＜名前＞ [ ＜項＞ ]
名前は，変数名となります。＜項＞は，変数の文字数の最大になります。この
変数を数値として使う場合は，十進数での桁数であり，数値マイナスになる場合
は，符号の一桁も加える必要があります。
４） 代入文
＜代入文＞ ：：＝ ＜名前＞ := ＜項＞
＜名前＞は＜変数宣言文＞で宣言した，変数名である必要があります。＜項＞
の内容が＜名前＞が表す変数に代入されます。変数名の最大長より，長い文字列
を代入しようとすると，異常となり，オートパイロットの処理を停止します。
例
var a[10];
a:={12345}; /* aは ｢12345｣という文字列になります */
a:={12345678901} /* aは１０文字までですのでエラーになります */
５） パラメタ
標準名以外を＜実行文＞とする場合の，＜パラメタ列＞は＜実行文＞の頭の＜
項＞で示す＜内容＞が以下のような場合にのみ，可能です。
＜内容＞：：＝ [ ＜仮パラメタ列＞ ] ＜仮パラメタを含む内容＞
＜仮パラメタ列＞ ：：＝ ＜名前＞ ｜
＜仮パラメタ列＞ ， ＜名前＞
＜仮パラメタを含む内容＞は，構文的には普通の文の並びです。ただし，この
中で＜仮パラメタ列＞内の＜名前＞で参照される＜名前＞は，対応する＜パラメ
タ列＞内の＜項＞の内容を意味します。
例
%Callnif { [TelNo,Id]
dial(TelNo);
type({.00+});
wait({10},stopt, {->},);
type( Id ) ;
type({\n})
};
Callnif( {ATDP 0301201234}, {PFF00XXX})
例 関数的な使いかた
%headtail { [input]
%h @getchar(input,1,1); /* inputの最初の文字 */
%t @getchar(input,@nochar(input),1); /* inputの最後の文字 */
im(h|t);
};
パラメタの最初と最後の文字を繋げて返す関数の定義になります。
６）演算子
演算子には，以下のような物があります。
＜演算子＞：：＝ && ｜ || ｜ < ｜ > ｜ <= ｜ >= ｜
== ｜ != ｜ = ｜ <> ｜ | ｜ + ｜ - ｜
* ｜ / ｜
＜単項演算子＞：：＝ ! ｜ + ｜ -
演算子が，一つの＜項＞の並びの中に複数個存在する場合には，以下の優先順
位に従って評価されます。同じ演算子，及び，優先度が同じ演算子は左から順に
評価されます。
最優先 ↑ !
｜ * /
｜ + -
｜ |
｜ = <> < > <= >= == !=
｜ &&
↓ ||
以下に各演算子の意味を記述します。
－ 文字列に対する演算
「|」 ：
左辺と右辺の文字列を結合した物を返します。
「=」 ：
左辺と右辺の文字列が，長さ，及び，その中身において，等しい場合に「Yes」，
等しくない場合に「No」を返します。
「<>」 ：
左辺と右辺の文字列が，長さ，又は，その中身において，等しくない場合に
「Yes」，等しい場合に「No」を返します。
%a {aaa} | {bbb}
aは｢aaabbb｣になります｡
%left {12rt};
%comp left = {12rt};
compは｢Yes｣になります｡
%comp2 left = {1234};
comp2は｢No｣になります｡
－ 数値に対する演算
「+｣｢-｣｢*｣｢/｣ :
それぞれ，加算，減算，乗算，除算を行います。左辺，及び，右辺は，数字だ
けの文字列，又は，数字列の前に半角の符号「+｣｢-｣を付けた物とします。それ以
外の文字列が，左辺，又は，右辺に来た場合，０として計算します。０で割った
場合の結果は保証しません。
「<｣｢>｣｢<=｣｢>=｣｢==｣｢!=｣ :
それぞれ，数値としての比較を行い，「Yes」，「No」を返します。
%a {1}+{5}; aは｢6｣
%a 1 +{5}; aは｢6｣
(数字は括弧を付けなくても数字列のみの，＜因子＞です）
%a (1+7)*2; aは｢16｣
%a {Nyaaao} + 1; aは｢1｣
%a ({1} | {5})*2; aは｢30｣
（１と５を文字列として繋げると，１５になります。）
var left[5];
left:=30;
%comp left==10*3; compは｢Yes｣です
－ 論理演算
「!」 ：
＜単項演算子＞であり，右辺が「Yes」の場合は，「No」を返します。それ以外
の場合は，「No」を返します。
｢&&｣｢||｣：
各々，論理積と，論理和を取ります。つまり，「&&」の場合は，両辺が「Yes」
の場合に，「Yes」を返します。「||」の場合は，どちらかの辺が「Yes」の場合
に，「Yes」を返します。それ以外は「No」を返します。
４．名前の有効範囲
＜宣言文＞で＜名前＞に＜内容＞となる文字列を対応させた場合，その有効範
囲はその時点での実行レベルが終わるまでです。つまり，その＜宣言文＞を含む，
最小の対になる「{」「}」の間，又は，その＜宣言文＞を含む，最小の＜名前＞
による定義の＜内容＞部分のいずれか小さい方です。
その実行レベルから，呼び出される実行レベルでは，上のレベルでの宣言が有
効です。
有効範囲を超えると，宣言前に同一名で有効であった上位のレベルの＜宣言文
＞があれば，それが再び有効になります。
同一レベルで，同一名の宣言を行うと，前の宣言は意味を失います。
最上位のレベルより，上の仮想的なレベルで定義されている，＜宣言文＞が標
準名です。標準名には次章に示すものがあります。現在ある標準名は実行された
場合にしか意味を持ちません。従って，文字列が必要な＜パラメタ列＞内の＜項
＞にこれらの＜名前＞を指定することはできません。
５．標準名による実行文
以下のような種類の標準名による実行文があります。
－ ホスト／通信回線の設定
－ MOPTERMの動作モードの設定
－ 電話回線の接続／切断
－ 回線へのデータの送信／受信
－ オートパイロットの実行制御
－ 文字列操作
－ 状態参照
－ ファイル操作
－ メモ操作
５．１ ホスト／通信回線の設定
モデムの種類／ホストに応じて設定して下さい。Ｎｉｆｔｙ等の標準的なセン
ターの場合は，タウンズメニューでの回線の設定のみで，あまり気にしなくても
良いと思いますが。
１）baud(ボーレート)
回線のボーレートを指定します。指定できる値は以下のものです。
{300},{600},{1200},{2400},{4800},{9600},{19200}
ただし，{19200}は動作しない機能があります。省略値は，タウンズメニューで
指定した値です。T-OS V2.1上では {9600}も使用できません。
２）xon({Yes}／{No})
通信回線がＸ－フロー制御をするか，否かを指定します。Ｘ－フローありを指
定した場合でも，Ｘ－ＭＯＤＥＭ動作中は，Ｘ－フローは行いません。
省略値は，タウンズメニューで指定した値です。
３）stopbit({1}／{2})
ストップビットを１又は２に設定します。
省略値はタウンズメニューで指定した値です。
４）parity({None}/{Odd}/{Even})
パリティを，なし，奇数，偶数にそれぞれ，設定します。
省略値はタウンズメニューで指定した値です。
５）lineend({CR}／{LF}／{CRLF})
通常の送信で，行の終わりを以下のようにします。
ＣＲ＝ ０Ｄ ＬＦ＝０Ａ ＣＲＬＦ＝０Ｄ０Ａ （１６進数）
省略値はＣＲです。
６）lineendt({CR}／{LF}／{CRLF})
文書の送信で，行の終わりを以下のようにします。
ＣＲ＝ ０Ｄ ＬＦ＝０Ａ ＣＲＬＦ＝０Ｄ０Ａ （１６進数）
省略値はＣＲです。
７）flyingx({Yes}／{No})
Flyng-Xを使うか，否かを設定します。Flying-Xは，ＭＮＰのモデムを使用時に
X-MODEMによる，バイナリー転送を高速化するための物です。アイデアは，NIFTY-Serve
，プログラマーズ・フォーラムＳＹＳＯＰ／フィンローダさんによるものです。
ＭＮＰ以外の接続形態では使用できません。（エラーが続発して，使えないでし
ょう。）
省略値はＮｏです。
８）dataleng({7bit}／{8bit})
データ長を設定します。
省略値はタウンズメニューで指定した値です。
９）rscs({Yes}／{No})
ＲＳ－２３２ＣのＲＳ／ＣＳ線によるフロー制御を行います。これを指定する
場合はモデム側でも，ＲＳ／ＣＳ線によるフロー制御を設定してください。ＭＮ
Ｐのモデムで有効です。
省略値はＮｏです。
１０）flyline({1～4})
文書ファイル，又は，メモをセンターに対して送信する際に，その文の改行が
エコーバックされてくる前に何行の，文を送信するかを指定します。省略値は３
であり，Ｎｉｆｔｙではこれでうまくいきますが，応答が遅いセンターでは少な
い値に設定して下さい。（例えばＰＣ－ＶＡＮは {1} ）。
１１）portno({0～4})
RS-232Cのポートの番号です。０以外は，拡張ボックスのポートになります。
省略値は 0（内蔵ポート）です。
１２）port0(種別) Ver0.99t以降サポート
以下の種別で，内蔵ＲＳ２３２Ｃポートの接続形態を指定します。省略値は
autoです。
auto:モデムカードが入っている場合内蔵モデム, そうでない場合外部RS232C
in :内蔵モデムカード（装備していないと，動作しません。）
out :外付けモデム(外部RS232C)（接続されていないと，動作しません。）
例
port0({out})
１３）code(コード名)
以下のコード名で，ホストのコードを指定します。省略値はシフトＪＩＳです。
コード名:sjis シフトJIS
jis シフト無JIS(83JIS)
ojis シフト無旧JIS(78JIS) Ver0.99t以降サポート
euc Externded Unix Code Ver0.99t以降サポート
例 新ＪＩＳコードのホストに接続する。
code({jis})
５．２ MOPTERMの動作モードの設定
MOPTERMの動作モードを，処理や，好みに応じて，変更するための物です。
１）click({Yes}／{No})
キー入力時のクリック音を出すか，否かを指定します。
省略値は，Ｙｅｓです。
２）logprint({Yes}／{No})
受信文字の印刷を行うか，否かを設定します。
省略値はＮｏです。
３）nattou({Yes}／{No})
通信画面でドット単位のスクロールを行うか否かを指定します。
省略値はＮｏです。
４）sendtype({Line}／{Ch/1}／{Ch/2})
ホストに対する送信を，行単位で行うか，文字単位で行うかを指定します。
Line ：行単位で送信することを指定します。
Ch/1 ：文字単位で送信します。２バイトのコードを持つ文字（漢字）
に対してバックスペースを行う場合，１つのバックスペースを送
信します。
Ch/2 ：文字単位で送信します。２バイトのコードを持つ文字（漢字）
に対してバックスペースを自動的に２つ，送信します。
Ｎｉｆｔｙのようなホストに対して，文字単位で送信する場合はＣｈ／２を指
定して下さい。
省略値は｢Line｣です。
５）doschar({文字})
通信入力行の１カラム目に，この文字があると，続く文字列はＭＳ－ＤＯＳの
コマンドと見なして処理されます。
省略値は 「%」になっています。
６）pilotch({文字})
通信入力行の１カラム目に，この文字があると，続く文字列はオートパイロッ
トの制御文と見なして処理されます。
省略値は 「$」になっています。
７）ctrl({Yes}／{No})
ｃｔｒｌ系の制御コードによるカーソルの移動を行うか，否かを指定します。
回線上のゴミで，カーソルが移動するのを防ぐためにはＮｏにしておく必要があ
ります。
省略値はＮｏです。
８）esc({Yes}／{No})
ＥＳＣシーケンス（ＦＭ系，ＡＮＳＩの一部）の処理を行うか，否かを指定し
ます。いたずらによる，画面の破壊を防ぐためには，Ｎｏにしておく必要があり
ます。
省略値はＮｏです。
９）setoak(文字列)
ＯＡＫ２のモードをセットします。文字列は以下の文字で構成されなくてはな
りません。そして，各々の文字の意味に従って，ＯＡＫ２のモードをセットしま
す。
J：漢字辞書モード
R：ローマ時モード
K：カタカナモード
H：ひらがなモード
Z：全角モード
例えば，漢字，全角，ローマ字入力，ひらがなにセットする場合は，
setoak({JZRH})
と，なります。省略値は，英字のみになっています。
１０）dispecho({Yes}／{No})
ファイル，及び，メモの送信時にセンターから，送り返された文字列を表示す
る場合にｙｅｓにします。省略時はｎｏです。
ｎｏの場合は，タウンズから送信したデータを表示し，送信中のセンターから
のデータは表示しません。ＭＮＰのモデムをお使いの場合は，ｙｅｓに，それ以
外の場合はＮｏをお勧めします。
１１）compath(パス名)
MS-DOSコマンド発行時に，コマンドプロセッサーとして使用する，プログラム
(Shell)を指定します。省略時は，「C:\\COMMAND.COM」になっています。
タウンズＯＳから起動する場合は，省略値のままで良いと思いますが，MS-DOS
から起動する場合は，使用するCOMMAND.COMを参照できるような形式で，指定して
下さい。MS-DOSからの起動については，他にも多くの注意が必要ですので，一般
には，お勧めできかねます。
例えば，D:がMS-DOSの起動ドライブとすると「compath({D:\\COMMAND.COM})」
のように指定します。
１２）crmode({Yes}／{No})
Ｎｏの場合，ホストからの改行コードとして，ＣＲ又は，ＬＦの片方を受け取
った時点で，カーソルの復帰，改行を行います。Ｙｅｓの場合は，ＣＲで，復帰，
ＬＦで，改行を行います。省略時は，Ｎｏの動作を行います。
１３）bellfile(ファイル名)
ＳＮＤ形式のＰＣＭデータの入ったファイルを指定して，ＣＴＲＬ－Ｇのベル
音として登録します。MOPTERM起動時に，起動時のディレクトリ内に「BELL.SND」
というファイル名で，ＳＮＤデータがある場合は，それが自動的に登録されてま
す。
この文では，既に登録されているベル音のデータがある場合は，それを置き換
えることになります。
例
bellfile({G:\BELL.SND})
１４）visibell({Yes}/{No})
Ｙｅｓを指定すると，CTRL-Gによるベル音発生時，及び，オートパイロットの
snd文実行時（音を出す時）に，画面が明滅します。省略値はＮｏです。
耳の不自由な方向けの機能です。この機能があれば，通信で，耳の不自由な方
のハンディキャップは，ありません。
１５）backclr(r,g,b)
通信画面のバックの色を指定します。３つのパラメタは，それぞれ，赤，緑，
青の３原色の輝度をあらわし，０～２５５までの数値です。省略値は，全て０と
した黒になっています。
例 バックの色を緑がかった，グレーにする。
backclr(64,128,64)
１６）setpf(n,text)
ＰＦキーにオートパイロットの制御文を登録できます。ｎがキーの番号１～２
０であり，ｔｅｘｔが登録する文字列です。文字列は，最大８０バイト（半角文
字）までです。これを越える大きさのオートパイロットは，別ファイルに作成し
て，呼び出すようにして下さい。
また，ＰＦキーは，テンキー無のキーボードでは，１～１２までしかありませ
んので注意して下さい。
例
setpf(2,{#G:\NEM\MAINPROC.PLT})
１７）tab(桁数)
水平タブを設定する，桁数の間隔を指定します。１以上，８０以下の値で，省
略値は，８です。水平タブは，文字の入力フィールドで有効です。
１８）retmark({Yes}/{No})
改行マーク，及び，エンドマーク（ＥＯＦマーク）の表示，非表示の切替えを
します。省略値は，表示です。
１９）shiftl({Yes}/{No}) Ver0.99までの機能
シフトが，ロックされる状態にします。つまり，Ｙｅｓの場合は，シフトキー
を一回押す事で，シフト状態になり，シフト状態で，シフトキーを一回押す事で，
シフト状態を解除します。省略値は Ｎｏです。
親指シフトには影響しません。親指シフトキーボードの場合は，ローマ字入力
を行わないと，一本指での入力はできません。
T-OS V2.1での，FEPでは アプリ側でこれを行う事が難しくなりました。Ver2.01
以降はサポートしていません。
２０）account(ファイル名,センター名［,分あたりの金額］)
センターへのアクセス終了時に，課金情報を指定されたファイルに書き出しま
す。ファイル名は３０文字まで，センター名は２０文字まで指定できます。
分あたりの金額は指定しなくてもかまいません。指定された場合，上のバー上に
アクセス時間の表示と合わせて，料金の表示も行います。
課金情報は，１行にセンター名，アクセス開始日付・時刻，アクセス時間，料金
を並べた物です。アクセス終了時にファイルの最後に追加していきます。
２１）hostmode({Yes/no})
受信したデータを，送信側にエコーバックするか否かの指定です。MOPTERMをホ
ストにする場合に使います。 省略値はNoです。
２２）hostplt(パス名)
MOPTERMのオートパイロットでホスト運用を行う場合に指定します。これが実行
されると，MOPTERMは RS-232CのCD(キャリア検出)信号線を監視し始めます。
CD線が, offからonになった場合，パス名で指定されたオートパイロットを起動
します。そして，そのオートパイロット実行中に，CD線が, OnからOffになった場合
そのオートパイロットの処理を，中断します。中断は，オートパイロットが，何ら
かの処理で，待ちに入った(wait文等)時に，行われます。
パス名として，空の文字列を指定すると，CDによる，オートパイロットの起動は
解除されます。
２３）printer({fm}/{esc/p})
接続したプリンターの種別を設定します。
fm :FMシーケンス(省略値)
esc/p:ESC/Pシーケンス
５．３ 電話回線の接続／切断
電話回線の接続を行ったり，切断したりするものです。
１）dial(パラメタ)
パラメタ ：接続方法，電話番号
パラメタは，ダイヤル回線の場合，{ATDP 電話番号}の形式，プッシュ回線の
場合，{ATDT 電話番号}です。パラメタで指定された形式で電話をかけます。モ
デムから，｢BUSY｣が返る場合には，再度，接続を行うモデムコマンドを発行しま
す。「CONNECT」が帰った場合に，接続に成功したと見なします。うまくセンタに
接続できない場合（「NO CARRIER｣等）は手続の実行を停止します。
うまく接続できると，接続中になります。
例
dial ({ATDP 01201234})
２）discon
電話を切ります。これにより，非接続中になります。接続中の状態でのみ実行
可能であり，非接続中の場合は意味がありません。パラメタはありません。パラ
メタを指定すると誤りになります。
回線の切断は，ＤＴＲ信号線を，Ｌｏｗレベルにすることで行っています。Ａ
ＩＷＡのモデムで，工場出荷時に，ＤＴＲ信号線を無視するモードになっている
物があります。有効とするように設定して下さい。
３）dialone({ ATDP 電話番号} ,文１ ,文２)
指定した電話番号に一回だけ電話をかけ，うまくダイアルされた場合に文１を
実行し，そうでない場合に文２を実行します。うまくダイアルできたか否かは，
モデムが「CONNECT」を返すことで確認します。ATDPの部分は，モデムのコマンド
に変更して下さい。
５．４ 回線へのデータの送信／受信
回線上のデータを，ファイルに受信したり，ファイルの内容を送信したりする
ものです。
１）type(文字列)
文字列を送信します。文字列の中で「\n」は改行を表します。
２）send(文字列)
３）sendx(文字列)
４）sendy(文字列)
文字列：送信するファイルのパス名，
文字列をファイル名（パス名）として，ファイルの中身を送信します（ファイ
ル送信処理）。すでに，ファイル送信，受信中の場合は失敗します。ファイルが
ない場合，アクセスできない場合も失敗します。
失敗した場合は手続を停止します。
sendは無手順のテキストファイル，sendxはX-modemの転送を，sendyはY-modem
の転送を，行います。
５）receive(文字列)
文字列：受信するファイルのパス名，
文字列をパス名として，そのファイルに受信内容を格納し始めます。（ファイ
ル受信処理）stoprecが実行されるまで格納を行います。すでに，ファイル送信，
受信中の場合は失敗します。ファイルへのアクセスができない場合も失敗します。
失敗した場合は手続を停止します。
６）stoprec
ファイル受信処理を終了します。
７）receivex(文字列)
８）receivey(文字列)
文字列：受信するファイルのパス名，
文字列をパス名として，そのファイルにX-MODEM/Y-MODEMで受信した内容を格納
します。（ファイル受信処理） すでに，ファイル送信，受信中の場合は失敗し
ます。ファイルへのアクセスができない場合も失敗します。
失敗した場合は手続を停止します。
９）writelog(ファイル名)
バックスクロールのためにログバッファに入っているデータ（最近，受信した
２５５Ｋ文字分）を，指定したファイルに書き出します。
１０）received(ファイル名)
基本的にｒｅｃｅｉｖｅと同じですが，ファイル名の後に「．月日」という修
飾を付けます。月は１月から９月までが１～９の数字，１０月～１２月がＡ～Ｃ
の英字になります。
例えば，received({FTOWNS}); を １１月１４日に実行すると，「FTOWNS.B14」
というファイル名で，ログが作成されます。
なお，既存の同名ファイルがある場合は，そのファイルに追加します。
１１）break
一定時間，ブレーク信号を送信します。
１２）checkbrk
ブレーク信号を受信している間に，この文を実行すると{Yes}が返ります。
そうで無い場合，{No}が返ります。オートパイロットでホストを作成する場合等
に使います。
５．５ オートパイロットの実行制御
受信した文字列や，ユーザの指示に応じて，制御文の実行順序を変えたり，ユー
ザに実行状態を表示したりするのに使います。
１）wait( パ０,パ１,パ２,パ３,パ４,パ５,・・・・・・・)
パ０：｛時間｝ ：最大待ち時間（秒）
パ１：｛処理０｝：最大待ち時間経過時の処理
パ２，４，・・ 文字列１，２， ：受信を待つ文字列ｎ
パ３，５，・・ 処理１，２， ：文字列ｎが入力された際の処理ｎ
指定したいずれかの文字列の受信を待ちます。最初の時間は，最大の待ち時間
で単位は秒です。この時間内にいずれの文字列も受信しなかった場合は処理０を
行います。文字列ｎが入力された場合は処理ｎを行います。
文字列の中で「\n」は改行を示します。
実行された文が値を持つ場合は，その値が，wait文の値として返ります。
例
wait ({30}, {stop}, {＞}，)
３０秒間，「＞」の受信を待ちます。もし，３０秒の間，「＞」の受信がなか
ったなら，制御文の実行を停止します。
もし，受信した場合は，次の処理を行います。
２）stop
制御文の実行を終了します。最後に記述された制御文の実行後はこの制御文が
なくても停止します。
３）stopterm
ＭＯＰＴＥＲＭを停止します。
４）case(a, c1,st1, c2,st2, c3,st3, ...)
ａが，ｃ１と等しい場合は，ｓｔ１を評価し，実行します。一般にｎ番目のｃ
ｎと等しい場合，ｓｔｎを評価し，実行します。ｃｎが空である場合，ｓｔｎは
必ず実行され，それ以降の比較は行われません。
５）loop(a)
ａを評価し，実行します。もし，結果が，「Yes」なら，再度，ａを評価し，実
行します。これを，ａの結果が「Yes」でなくなるまで行います。
６）input(表題) 又は input(表題,{c}/{u},初期値)
表題をして表示し，入力行を出します。ユーザが，文字をを入力し，改行を行
うと，その改行までの文字が返ります。
２番目のパラメターで，{c},又は,{u}が指定された場合は，入力待ち状態で，
回線からの受信が可能です。ＲＴ中の入力等に利用可能です。{u}の場合は，
画面の下側に，タイトル無しで，通常の送信入力行と同じ形式の表示をします。
３番目の初期値は，入力行に最初から表示される，文字列を指定します。
７）select(表題,時間,文0 ,項目1,文1 ,項目2,文2,...)
表題を表示し，その下に，マウスクリックするボタンとして，項目ｎを表示し
ます。各項目が左クリックされた場合は，対応する文が実行されます。指定され
た時間（秒）内にクリックされない場合，又は，右クリックされた場合は，文０
が実行されます。
８）chat({Yes}/{No})
オートパイロット実行中の，キーボードからの送信を許可，不許可とするもの
です。許可した形の場合，マニュアルでの動作のバックグランドで，オートパイ
ロットが動作するような形になります。
９）display(任意の文字列)
オートパイロット処理の処理状況を画面に表示する際に使用します。文字列を
表示するだけで，特に処理に影響はありません。
１０）footnote(テキスト) 又は footnote(テキスト,{b})
テキストを，画面の最下段に表示する文です。テキストは，半角７０文字（全
角３５文字）までの文字列でを指定します。改行は，必要ありません。また，エ
スケープや，コントロールコードは使用できません。また，表示は，オートパイ
ロットの実行中のみです。
例 「動作中」という文字列を表示する。
footnote({動作中})
２つ目のパラメタで，{b}を指定した場合は，画面の下側に最大１２個のボタン
を表示します。このボタンは，waitxで拾うためのアクションになります。この場
合，テキストは，４文字（全角２文字）単位で区切られて，ボタンの表書きに使わ
れる事になります。１つのボタンが４文字（全角２文字）ですので，１２個のボタ
ン全てを使用すると，４８文字のテキストになります。
文字数は，ボタンの数×４文字でなくてはいけません。
１１）dispoff({Yes}/{No})
バックスクロールするディスプレイへの表示を，中止する指定です。一旦，｢Yes｣
を指定すると，全ての処理で，バックスクロール画面への表示が停止します。｢No｣
を指定すると，表示を再開します。
１２）snd(ファイル名)
ＰＣＭデータの入った，ＳＮＤ形式のファイルを指定して，その内容を発音し
ます。
１３）filesel 又は, filesel(ファイルタイプ)
ファイルセレクターを表示し，ユーザにファイル名を選択してもらいます。応
答として，ファイル名が返ります。ファイルタイプは，３文字までの大文字の英
数字で，ファイル名の「.」の後の部分が，ここに指定した物と同じもののみ一覧
表示します。一覧の絞り込みのためのもので，直接ファイル名を入れた場合のチ
ェックには使用されません。
１４）waitx( パ０,パ１,パ２,パ３,パ４,パ５,・・・・・・・)
処理はwait文とほぼ同じです。但し，ＰＦキーが押された場合，又は，マウス
の右ダブルクリックが行われた場合に，タイムオーバーと同じ形式で，終了しま
す。
その際，xtype文で，どのような処理で終了したかを知る事が可能です。
ＰＦキーは，通常のキー入力モードには無関係に，押された事のチェックを行
いますので，特に chat({Yes}) のようなモードにしなくて，ＯＫです。
xtype文で返る値は以下の通りです。
－ xtype
タイムオーバー
-2
ダブルクリックされた時
0 : バックスクロールの部分
1～9 : 各々，メモ１～９に対応するメモ画面（必ず，編集中）
-1 : 上の何れでもない部分でダブルクリックした場合。
ＰＦキーが押された場合
１０１：ＰＦ１キー
１０２：ＰＦ２キー
・ ・
・ ・
１１２：ＰＦ１２キー
下にボタンを表示している場合で，そのボタンがマウスで左クリックされた場合
２０１：左端のボタンがクリックされた
２０２：左から２番目がクリックされた
・ ・
・ ・
２１２：右端のボタンがクリックされた
ダブルクリックにより，終了した場合は，以下の文を使用可能です。
－ xline(a)
aは数値であり，その数値に従って，以下の内容を返す。
a = 0 クリックされた時の，マウス位置の行の内容
< 0 マウス位置より，さかのぼって，-a行目の内容
> 0 マウス位置から，a行 ,先の行の内容
マウス位置が，画面上の行の改行より右側部分にある場合，次の行の頭を指し
ているものとする。メモ画面上の行の場合，メモ画面がクローズされた後は，値
は返せない。
１４）crchg({Yes}/{No})
MOPTERMの文法では，一般的に，｢\n｣を CR+LFコードに置き換えます。この置き
換えを，有効にするか否かを指定します。この，文の目的は，一つは，｢\n｣をその
まま，扱う処理のため，，もう一つは，置き換え処理をしない事による，処理の
高速化のためです。
１５ plane(<format>,<初期値1>,,,,,<初期値n>);
一つのウィンドウの中に，文字入力や選択のためのボタンを複数並べるための
物です。
○ <format>:行単位で，各行に置く要素を指定する。行要素間は改行入れて，区別
します。行要素は以下の何れかの形式。
コメント行 ｢c表示文字列｣
ラジオボタン行 ｢r表題/ボタン名1/ボタン名2/.../ボタン名n｣
テキスト入力行 ｢t表題/xxxxxxxx｣
(xの数だけの文字数が入力できるﾌｨｰﾙﾄﾞとなる。｢x｣が無い場合,
Max(127文字)とみなされる｡ ）
セレクト行 ｢s表題/ボタン名1/ボタン名2/.../ボタン名n｣
いずれも，１行を越えない範囲です。
セレクト行の，何れかが，押された場合，終了します。又，右クリックされた場合
にも終了します。終了とは，この分で表示したウィンドウを消し，この文の実行を終
了する事です。
○初期値n： ラジオボタン行と，テキスト入力行に対応して，上から順に，
初期値を与える事ができます。テキスト入力の場合，文字列，ラジオボタンの
場合，１～の数値を指定します。指定が無い場合，テキスト入力は空列，ラジ
オボタンは １が仮定されます。
○この文の返却値は最初の行から，順に，ﾗｼﾞｵﾎﾞﾀﾝ，ﾃｷｽﾄ，ｾﾚｸﾄのある行に対応し
て，１行づつ文字列が返却されます。ｺﾒﾝﾄの行に対応する返却行はありません。
ﾗｼﾞｵﾎﾞﾀﾝの行は，最後に選択されていたﾎﾞﾀﾝの番号。
ﾃｷｽﾄの行は，最後に入力されていた，文字列。入力がない場合，又は，右
クリックでキャンセルされた場合は空の文字列が返ります。
ｾﾚｸﾄの行は，その行のﾎﾞﾀﾝが押された事によって，終了した場合に，そのﾎﾞﾀﾝ
の，行の最初から順序（1～)。押されないで終了した（他の行のｾﾚｸﾄが押された
又 右ｸﾘｯｸされた）場合は，0が帰ります。
５．６ 文字列操作
オペランドで指定した文字列の操作を行う，関数的な処理です。
１）xc({16進数})
16進数で記述された，コードに対応する文字を返します。１文字は２桁の１６
進数に対応します。
２）im(文字列)
文字列をそのまま値として返します。｢@im( a )｣は，｢a」と同じ意味になりま
す。
３）tail(a,b,c) 又は tail(a,b)
ａという文字列を，後ろから検索して，ｂと同じ文字列があれば，それより後
ろを返します。もし，ｃが指定されていれば，ｂより後ろで，ｃという文字列よ
り前の部分，つまり，ｂとｃに挟まれた部分を返します。
｢display(@tail{akkcdeabbc},{a},{c})｣は,｢bb｣を表示します｡
４）head(a,b,c) 又は head(a,c)
ａという文字列を，前から検索して，ｃと同じ文字列があれば，それより前を
返します。もし，ｂが指定されていれば，ｃより前で，ｂという文字列より後ろ
の部分，つまり，ｂとｃに挟まれた部分を返します。
｢display(@head{akkcdeabbc},{a},{c})｣は,｢kk｣を表示します｡
５）body(a,b) 又は body(a,,c) 又は body(a,b,c)
もし，bが指定されていればａという文字列を，前から検索して，bと同じ文字
列があれば，それより後を返します。もし，cが指定されていれば，aを後ろから
検索してcという文字列より前の部分を返します｡ｂとｃが指定されていた場合は
ｂとｃに挟まれた部分を返します。
｢display(@body{akkcdeabbc},{a},{c})｣は,｢kkcdeabb｣を表示します｡
６）getchar(a,b,c) 又は,getchar(a,b)
ａという文字列の，ｂ文字目より後の部分です。ｃが指定されていた場合は，
ｂ文字目より後の，ｃ文字を取り出します。ｂがａの長さより長い場合は，空の
文字列になります。ｃが残りの長さより長い場合は，残りの全てになります。
７）getline(a,b,c) 又は getline(a,b)
ａという文字列の，ｂ行目より後で，ｃがあれば，ｃ行分を返します。
８）nochar(a)
ａの文字数を返します。
９）noline(a)
ａの行数を返します。
５．７ 状態参照
MOPTERMの処理状態を取り出す，関数的なものです。
１）laststr 又は laststr(a)
最も最近受信した，a文字の文字列を返します。aが指定されていない場合は，
６４文字分返します。 aの値は，１以上で１２８以下である必要があります。
なお，バックスクロール画面への表示を行っていない場合にも，この応答は返
ります。MOPTERMの起動直後で，指定した文字数分だけ受信していない場合は，頭
に半角空白文字を補った，文字列が返ります。
「%jobno @tail(@laststr,{番号},{のユーザ});」は，最も最近受信した文字
列の中で「番号」と「のユーザ」のあいだの部分になります。
２）day
発行した月日を返します。月は，１６進数一桁，その後に日付を二桁の十進数
で付けた３桁の形です。
３）linetime
電話回線の接続時間を秒単位でカウントし，その値を返します。接続前は「0」
を返します。切断後は，切断時の接続時間を返します。最大値は１０進数で７桁
ぐらいですが，そこまで使う人は，，，あまり，いないと思います。
接続とは，モデムが，「CONNECT」を返した時点からで，切断というのはMOPTERM
が，RS-232CのDTR信号線をＬｏｗレベルにすることを言っています。
４）linechck
接続状態か，否かを返す関数です。接続時は，「Yes」を，非接続時は「No」を
返します。
接続とは，モデムが，「CONNECT」を返した時点からで，非接続というのは，そ
の後，MOPTERMが，RS-232CのDTR信号線をＬｏｗレベルにした後の状態です。
５）daylong
現在の日付，時刻を以下の形式で返します。
｢YYYY/MM/DD WWW HH:MM:SS｣
YYYY:西暦 MM:月 DD:日 WWW :曜日(英字 3文字)
HH:時(24h) MM:分 SS:秒
「0」を，空白に置き換える事はしていません。
６）initdir
MOPTERM起動時のカレントディレクトリーのパスを返します。起動時のディレ
トリーにあるファイルのアクセス等に使います。
５．８ ファイル操作
ファイルの書き込み，読みだし等の操作を行います。
１）write(ファイル名,文字列)
指定したファイルの最後に,文字列を追加します。
２）read(ファイル名) 又は read(ファイル名,最初の行) 又は
read(ファイル名,最初の行,行数)
指定したファイルの中身を返します。最初の行が指定されている場合は，その
行，以降を返します。行数が指定されている場合は，その行数分だけ返します。
３）getcdir
カレントディレクトリーのパスを返します。形式は以下のような形です。
ドライブ名:\再上位のディレクトリー名\次のディレクトリー名\...
...最後のディレクトリー名
４）setcdir(ディレクトリーへのパス)
カレントディレクトリーを任意のパスに変更します。パスの指定は，getcdirで
得た形式に準拠します。指定されたパスへの変更に成功した場合は「Yes」，失敗
した場合は「No」を返します。
５）filechk(a)
ａというファイルが存在する場合に「Yes｣,存在しない場合に「No」を返します。
６）command(コマンド)
ＭＳ－ＤＯＳのコマンドとして処理します。処理結果の文字出力は画面に出ま
す。ただし，バックの画面がNAPLPSの描画モードの場合は，何も出ませんので注
意して下さい。
７）fopen(ファイル名)
ファイルの読み込みオープン処理。fread,fclose,ftellと組み合わせて使用す
る。オープンに成功すると「Yes」 失敗すると「No」を返す。
８）fread 又は fread(桁位置, 検索文字)
fopenで，オープンしたファイルの次の一行を返す。パラメタが与えられると，
次の行を検索して，指定された桁位置に，指定された文字のある，最初の行を返す
。
９）fclose
fopenと対にして使用する。ファイルの読み込み処理を終了する。
１０）ftell
最も最近，読み込んだ行の，ファイルの先頭からのバイト数を返す。この値は
必ず６桁の数値で表され，先行０を消す事はない。
例
%setline {
%line2 @fread;
var item[82];
item:=@ftell | { } | @getchar(line,1,3);
case(@getchar(line2,27,2),
{へ},{item:=item | @getchar(line2,23,4)},
,{item:=item | { }}
);
item:=item | @getchar(line,19,80);
madd(1,item);
};
mclear(1);
fopen({i:\FTOWNS1\mes15.log});
loop({
%line @fread(4,{/});
setline;
im(line <> {})
});
fclose
１１）diskrem
カレントドライブの，空きエリアの大きさを返します。単位は，バイトです。
Ｋバイトでないので，注意して下さい。
１２）naplps(ファイル名) or naplps(ファイル名,{add})
バックの画面をNAPLPS描画モードにし，ファイルの内容をNAPLPSのデータとして
描画します。{add}を指定すると，既に描画されている画面に上書きされます。
１３）napend
バックの画面をNAPLPS描画モードから，通常の文字のモードに戻します。
１４）copyfile(元ファイル,コピー先ファイル)
ファイルのコピーをします。上手く行くと{Yes}､失敗すると{No}が返ってきま
す。
１５）delfile(ファイル)
ファイルの削除をします。上手く行くと{Yes}､失敗すると{No}が返ってきま
す。
５．９ メモ操作
メモの内容を処理するものです。
１）mread(ファイル名［,メモ番号［,開始バイト位置［,読み込みバイト数］］］)
指定されたファイルの内容をＭｅｍｏのメモ番号番目に読み込みます。メモ番
号は作成済のメモの番号を指定する１～９の数字です。
（省略時はメモ番号１）
２）mwrite(ファイル名［，メモ番号］)
指定されたファイルにＭｅｍｏのメモ番号番目の内容を書き出します。メモ番
号は作成済のメモの番号を指定する１～９の数字です。
（省略時はメモ番号１）
３）mclear［（メモ番号）］
Ｍｅｍｏのメモ番号番目の内容を削除します。メモ番号は作成済のメモの番号
を指定する１～９の数字です。
（省略時はメモ番号１）
４）memo(a) 又は memo(a,最初の行) 又は memo(a,最初の行,行数)
ａ番目のメモの内容を返します。最初の行が指定されている場合は，その行，
以降を返します。行数が指定されている場合は，その行数分だけ返します。
５）madd(a,text)
ａ番目のメモの後ろに，textの内容を追加します。ａは，現在作成済のメモ
か，作成済のメモ＋１のメモで，１～９の範囲の番号です。
６）mlast
最後に作成されたメモの番号（最大のメモの番号）を返します。メモがまった
く作成されていない場合は，｢0｣が返ります。最大は９です。
７）mcheck
現在，メモ編集中の場合に，編集中のメモの番号が返ります。編集中でない場
合は，「0」が返ります。最大は，９です。
８）mopen(a) 又は mopen(a,ulx,uly,drx,dry［,type］)
メモウインドウをオープンします。a番目のメモは，この文の実行前に作成され
ている必要があります。また，現在編集中のウィンドウがある場合はエラーにな
ります。（mclose(1)等でクローズする必要があるでしょう。）
パラメタが，aのみの場合は，ウインドウの大きさ，及び，場所は，以前，オー
プンされた時の場所，又は，最初のオープンの場合は，マウスカーソル位置の周
辺です。
２番目以降のパラメタは，ウィンドウの画面上の位置，及び，大きさを指定す
るもので，左上の点と，右下の点の座標（ｘ，ｙ）になっています。
左上 (ulx,uly) 右下 (drx,dry)
ｘ座標は，左から右に０～６３９の値で表します。
ｙ座標は，上から下に２１～４５９の値で表します。
また，ウィンドウのサイズは，最低，ｘ方向に８０以上，ｙ方向に４１以上，
必要です。ｙ方向のサイズは，スクロールバーと，上のタイトル部分を含みます
ので，実際に使用できるのは，（指定した大きさ－２１）ドットの分です。
１文字半角は，横に８ドット，縦に２０ドット必要ですので，最低のウィンド
ウで，横１０文字，縦１行，最大で，横８０文字，縦２０行（半？）です。横の
文字数ははみ出すと，次の行に回り込みますが，縦は，半分だけ表示されます。
半分の行は，編集には使えませんが・・(^_^;。
例 メモ１を最大の大きさのメモウィンドウでオープンする。
mopen(1,0,21,639,459)
typeを指定すると，オートパイロットの制御専用の画面を作成することができ
ます。typeに 「w」を指定すると，オートパイロット以外の制御で，画面を閉じ
ることができなくなります。また，「r」を指定すると，「w」の制限の他に参照
のみとなり，手動で変更することができなくなります。
アップされたメッセージを見て，コメントを作るという作業をオートパイロッ
トの制御下でやるとすると，アップされたメッセージを「r」指定で表示しておい
て，「w」指定の，応答編集画面を出す，，と言ったぐあいに使います。
９）mclose(タイプ)
編集のメモウィンドウをクローズします。タイプによって，以下の動作を行い
ます。
1 : 編集状態を解除します。メモウィンドウそのものは表示したままです。
2 : 編集状態を解除し，表示も消します。その際，下位に重なったメモウィ
ンドウが画面上にある場合は，そのメモウィンドウが編集状態になります。
3 : 編集状態を解除し，表示も消し，メモとしての存在も消します。メモの
番号は，それ以降のものが，一つ，繰り下がります。
その際，下位に重なったメモウィンドウが画面上にある場合は，そのメ
モウィンドウが編集状態になります。
１０）nolmemo(メモ番号)
指定したメモ内の，文書の行数を帰します。
６．著作権
本文法の著作権はＮＩＦＴＹのモップ（ＰＦＦ００５７０）にあるものとしま
す。商用に本文法を使用する場合はご一報ください。フリーソフトウエアとして
の使用は自由ですが，この文法を使用するソフトウエアの配付には，この著作権
の記述も併せて配付することを義務とします。また，ユーザの混乱を避けるため
に，文法については中途半端な類似は避けてください。同じものとする場合は，
ユーザが同じ記述の制御文ファイルを共有できる程度に互換性のあるものにして
ください。
もっとも，厳しい対処をさせて戴くケースは，少し違うという文法を作成する
場合です。
何れの場合も，メールいただければ，対応いたします。
モップ（ＰＦＦ００５７０）
